本文从EXCEL《出库单》的设计出发，简要介绍设计《出库单》所涉及的公式及函数。
一、《出库单》设计
新建一个EXCEL工作簿，修改一张工作表的名称为“出库单”，如下图完成《出库单》表格框架设计。
在N2单元格输入公式：=TODAY()
在H5单元格输入公式：
=IF($E5*$F5,LEFT(RIGHT(” “&”¥”&$E5*$F5*100,COLUMNS(H:$P))),””)
注意：公式第一个&字符前” “代表一个空格，下同。
把H5中的公式向右复制到P5,再向下复制到P9。
在H10单元格输入公式：
=IF(SUMPRODUCT($E$5:$E$9,$F$5:$F$9),LEFT(RIGHT(” “&”¥”&SUMPRODUCT($E$5:$E$9,$F$5:$F$9)*100,COLUMNS(H:$P))),””)
把H10中的公式向右复制到P10。
在B10单元格输入公式：
=”大写：人民币”&SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(TEXT(INT(ABS(SUMPRODUCT(E5:E9,F5:F9))),”[DBNum2]”)&”元”&TEXT(RIGHT(TEXT(SUMPRODUCT(E5:E9,F5:F9),”.00″),2),”[DBNum2]0角0分”),”零角零分”,”整”),”零分”,”整”),”零角”,”零”),”零元零”,””)
到这里，《出库单》设计就算成功了，可以输入数据进行验证。
二、公式说明
N2单元格公式，用于提取当前日期。
H5:P9区域单元格公式，用于把每行记录中数量×单价所得金额进行拆分提取，并把提取值赋值给对应的单元格。
B10单元格公式，用于把E5:F9区域数量与单价乘积之和（即总金额），转换成中国式大写。
H10:P10区域单元格公式中创网，用于把E5:F9区域数量与单价乘积之和（即总金额）拆分提取，并把提取值赋值给对应的单元格。
三、涉及函数介绍
（一）TODAY函数
TODAY函数，可以得到系统的当前日期。TODAY函数是不需要参数的函数，其语法是TODAY（）。如：
N2=TODAY（）=2019年1月11日（本文编辑于2019年1月11日）
（二）COLUMNS函数
COLUMNS函数，返回所选择的某一个连续范围内的一系列单元格的总列数，其语法是COLUMNS（连续区域）。如：
COLUMNS(H:$P)=9
（三）RIGHT函数
right函数的功能是从字符串右端取指定个数字符。
语法：
Right(string, length)
Right(字符串, 返回字符长度)
参数：
String，必要参数。字符串表达，式，从中最右边的字符将被返回。如果 string 包含 Null，将返回Null。
Length，必要参数；为 Variant (Long)。为数值表达式，指出想返回多少字符。如果为 0，返回零长度字符串 (“”)。如果大于或等于 string 的字符数，则返回整个字符串，但并不增加其它字符。
如：
Right(“asdfgh”, 1)=h
Right(“asdfgh”, 2)=gh
Right(“asdfgh”, 6)= asdfgh
Right(“asdfgh”, 7)= asdfgh
图例中：=RIGHT(” “&”¥”&$E5*$F5*100,COLUMNS(H:$P))= ¥8925840（注意“¥”前有一个空格）
（四）LEFT函数
LEFT函数用于从一个文本字符串的第一个字符开始返回指定个数的字符。
语法：
LEFT( string, n )
LEFT(字符串, 返回字符长度)
参数：
string ，必要参数。字符串表达式其中最左边的那些字符将被返回。如果 string 包含 Null，将返回Null。
n ，必要参数；为 Variant (Long)。数值表达式，指出将返回多少个字符。如果为 0，返回零长度字符串 (“”)。如果大于或等于 string 的字符数，则返回整个字符串。
如：
LEFT(“asdfgh”)=a
LEFT(“asdfgh”,0)=””
LEFT(“asdfgh”,1)=a
LEFT(“asdfgh”,3)=asd
图例中：LEFT(RIGHT(” “&”¥”&$E5*$F5*100,COLUMNS(H:$P)))=” “(” “表示一个空格)
（五）IF函数
IF函数，根据指定的条件来判断其“真”（TRUE）、“假”（FALSE），根据逻辑计算的真假值，从而返回相应的内容。
语法：
IF(logical_test,value_if_true,value_if_false)
参数：
Logical_test 表示计算结果为 TRUE或 FALSE 的任意值或表达式。
Value_if_true logical_test 为 TRUE 时返回的值。
Value_if_false logical_test 为 FALSE 时返回的值。
图例中：
IF($E5*$F5,LEFT(RIGHT(” “&”¥”&$E5*$F5*100,COLUMNS(H:$P))),””)=” “(” “表示一个空格)
（六）SUMPRODUCT函数
SUMPRODUCT函数，返回相应的区域或数组乘积的和。
语法及参数：
SUMPRODUCT（array1,array2,array3,…）
Array1,array2,array3, … 为 2 到 30 个数组，其相应元素需要进行相乘并求和。
SUMPRODUCT（连续区域1,连续区域）
图例中：SUMPRODUCT($E$5:$E$9,$F$5:$F$9)=258862.81
（七）ABS函数
ABS函数，用于计算某一数值的绝对值。
语法及参数：
ABS(number)
Numberexcel取绝对值函数公式，必要参数，表示要计算绝对值的数值。
（八）INT函数
INT函数，将一个要取整的实数向下取整为最接近的整数。
语法及参数：
INT（number）
number，必要参数，要取整的实数。
如：
INT(17.5)=17
INT(-12.5)=-13
图例中：INT(ABS(SUMPRODUCT(E5:E9,F5:F9)))=258862
（九）TEXT函数
TEXT函数，将数值转换为按指定数字格式表示的文本。
语法及参数：
TEXT(value,format_text)
Value 为数值、计算结果为数字值的公式，或对包含数字值的单元格的引用。
Format_text 为“单元格格式”对话框中“数字”选项卡上“分类”框中的文本形式的数字格式。Format_text参数代码代码较多，读者可以上网搜索了解，图例中”[DBNum2]”代表[$-804]G/通用格式。
如：
TEXT(“23″,”[DBNum2]0角0分”)=贰角叁分
TEXT(“23″,”[DBNum2]”)=贰拾叁
TEXT(“23″,”[DBNum2]G/通用格式圆”)=贰拾叁圆
图例中：TEXT(INT(ABS(SUMPRODUCT(E5:E9,F5:F9))),”[DBNum2]”)=贰拾伍万捌仟捌佰陆拾贰
（十）SUBSTITUTE函数
SUBSTITUTE函数，在某一文本字符串中替换指定的文本，即在文本字符串中用 new_text 替代 old_text。
语法及参数：
SUBSTITUTE(text,old_text,new_text,[instance_num])
Text，必要参数。为需要替换其中字符的文本excel取绝对值函数公式，或对含有文本的单元格的引用。
Old_text，必要参数。为需要替换的旧文本。
New_text，必要参数,但有默认值空。用于替换 old_text 的文本。
Instance_num 为一数值，用来指定以new_text 替换第几次出现的 old_text。如果指定了 instance_num，则只有满足要求的 old_text 被替换；如果缺省则将用 new_text 替换 TEXT 中出现的所有 old_text。
图例中，四层嵌套SUBSTITUTE函数主要是对中国式金额大写特殊情况进行替换：
SUBSTITUTE(TEXT(INT(ABS(SUMPRODUCT(E5:E9,F5:F9))),”[DBNum2]”)&”元”&TEXT(RIGHT(TEXT(SUMPRODUCT(E5:E9,F5:F9),”.00″),2),”[DBNum2]0角0分”),”零角零分”,”整”)=贰拾伍万捌仟捌佰陆拾贰元捌角壹分
SUBSTITUTE(SUBSTITUTE(TEXT(INT(ABS(SUMPRODUCT(E5:E9,F5:F9))),”[DBNum2]”)&”元”&TEXT(RIGHT(TEXT(SUMPRODUCT(E5:E9,F5:F9),”.00″),2),”[DBNum2]0角0分”),”零角零分”,”整”),”零分”,”整”)=贰拾伍万捌仟捌佰陆拾贰元捌角壹分
SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(TEXT(INT(ABS(SUMPRODUCT(E5:E9,F5:F9))),”[DBNum2]”)&”元”&TEXT(RIGHT(TEXT(SUMPRODUCT(E5:E9,F5:F9),”.00″),2),”[DBNum2]0角0分”),”零角零分”,”整”),”零分”,”整”),”零角”,”零”)=贰拾伍万捌仟捌佰陆拾贰元捌角壹分
SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(SUBSTITUTE(TEXT(INT(ABS(SUMPRODUCT(E5:E9,F5:F9))),”[DBNum2]”)&”元”&TEXT(RIGHT(TEXT(SUMPRODUCT(E5:E9,F5:F9),”.00″),2),”[DBNum2]0角0分”),”零角零分”,”整”),”零分”,”整”),”零角”,”零”),”零元零”,””)=贰拾伍万捌仟捌佰陆拾贰元捌角壹分
说到这里，本文也该结尾了，希望本文对您制作《出库单》等中国式凭证、账页，学习了解excel公式、函数有所帮助。
